Two-trains-interaction with photosensors

Now that we can control 1 train with arduino, it’s time to add a second one.
We made a track where the two trains share a part of the track, but also each have an individual part of the track. In this case we can let a train wait on his own track, while the other train uses the shared part of the track.
How do we know when the other train can start? We will be using photosensors for this.

On this track we placed two photosensors. What we want is when a train goes over a photosensor, it has to be stopped and the other train has to be started.

Our arduino circuit now looks a bit more complicated than in our previous post:

The IR-LED stays the same, connect it to an arduino port (we use port 13) and use a resistor to connect it to ground so it doesn’t burn out (see our previous post).
New in this schematic are the two photoresistors (LDR) which we connect to 5V and, the other leg of the sensor, to an analog port to read the value. They are analog inputs and the value we will get back will be between 0 and 1024. In this example we use the analog ports A0 and A1 on the arduino. Also connect another resistor after the photoresistor (they will be in series). This will create a voltage divider: more information here.

The code looks like this:

#include <legopowerfunctions.h>

LEGOPowerFunctions lego(13);
int sensorInnerTrack = A0;
int sensorOuterTrack = A1;

int threshold = 500;
boolean wasInnerTrackTrainOnSensor = false;
boolean wasOuterTrackTrainOnSensor = false;

What does this do so far?
We import the LegoPF library and define that our IR-LED is connected to port 13.
We also define our two photoresistors which are connected to analog input ports A0 and A1.
We also need some kind of threshold value. We expect the photoresistors to give this value or lower when a train is going over the photoresistor.
The booleans wasXTrackTrainOnSensor are necessary to know the previous state of the train. We don’t want to keep stopping the train when it’s still on the photoresistor, and if the two trains are “parked” on the photoresistors we need to know which one was driving before so we can start the other one.

Next up is the setup method:

void setup(){
   Serial.begin(9600);
   startOuterTrackTrain();
}

Serial.begin(9600) is for ‘debugging’ purposes. You need to write this in the setup method if you want some output in the Serial Monitor later.

We start one of the trains, it doesn’t really matter which one. We do this by calling an extra method we defined next to the loop and setup method. We will also need methods to start the other train and two methods to stop the trains:

void startOuterTrackTrain(){
   lego.SingleOutput(0, PWM_FWD4, BLUE, CH2);
}
void startInnerTrackTrain(){
   lego.SingleOutput(0, PWM_FWD4, BLUE, CH1);
}
void stopOuterTrackTrain(){
   lego.SingleOutput(0, PWM_FLT, BLUE, CH2);
}
void stopInnerTrackTrain(){
   lego.SingleOutput(0, PWM_FLT, BLUE, CH1);
}

The PWM_FLT and PWM_FWD4 are the speeds of the train (stop and speed 4), and the other parameters tell us on which channels the signal will be sent. Our inner track train drives on the channel BLUE CH1 and the outer track train is on BLUE CH2.

The loop method will go like this:

void loop(){
   Serial.print(analogRead(sensorInnerTrack));
   Serial.print("\t");
   Serial.println(analogRead(sensorOuterTrack));

   boolean isInnerTrackTrainOnSensor = analogRead(sensorInnerTrack) < threshold;
   boolean isOuterTrackTrainOnSensor = analogRead(sensorOuterTrack) < threshold;

   if(isInnerTrackTrainOnSensor && !wasInnerTrackTrainOnSensor){
      startOuterTrackTrain();
      stopInnerTrackTrain();
   } else if(isOuterTrackTrainOnSensor && !wasOuterTrackTrainOnSensor){
      startInnerTrackTrain();
      stopOuterTrackTrain();
   }

   wasInnerTrackTrainOnSensor = isInnerTrackTrainOnSensor;
   wasOuterTrackTrainOnSensor = isOuterTrackTrainOnSensor;
}

The Serial.print-methods in the beginning are our ‘debug’ lines. It will print things to the Serial Monitor which you can find in the Arduino IDE under Tools > Serial Monitor.

We have to read the sensor values by using analogRead(). We immediately check if this is higher or lower than our predefined threshold value. This way we know if the train is standing above one of the sensors or not.
After that we need to stop and start the trains. If a train is standing over a sensor and wasn’t previously there, we need to stop that train and start the other one.
And last but not least, store the value of the sensor in the ‘previous’ value state so we know in the next loop if the train was standing over the sensor or not.

After Thoughts:

• This way of working is fine, maybe even better suited if you work with 9V trains because your sensor will allow you to stop and start any train on that specific track.
• With our Power Functions experiment, however, we run into complications as this setup needs to be fixed. Fixed in the way that you need to know which train is where at all times, because we need to send the signals to the trains on specific channels, we can’t just let any random train stop at the sensor.
• If we were would drag this project further out, we would need to have the trains running on a fixed parcours at all times.
• To make it more dynamic we’d need a way to indentify the trains at certain key points in the track. For this we’re looking at RFID but at the time of writing our hardware hasn’t arrived yet so we don’t know how succesful this solution can be.